DS18B20.ino

Go to the documentation of this file.

#include "GPIO.h"
#include "OWI.h"
#include "Slave/OWI.h"

static const uint8_t FAMILY_CODE = 0x28;

enum {
  CONVERT_T = 0x44,             
  READ_SCRATCHPAD = 0xBE,       
  WRITE_SCRATCHPAD = 0x4E,      
  COPY_SCRATCHPAD = 0x48,       
  RECALL_E = 0xB8,              
  READ_POWER_SUPPLY = 0xB4      
} __attribute__((packed));

struct scratchpad_t {
  int16_t temperature;          
  int8_t high_trigger;          
  int8_t low_trigger;           
  uint8_t configuration;        
  uint8_t reserved[3];          
} __attribute__((packed));

// Slave device one wire access; use random rom code
Slave::OWI<BOARD::D7> owi(FAMILY_CODE);

// Scratchpad with temperature, triggers and configuration
scratchpad_t scratchpad = {
  0x0550,                       
  75,                           
  70,                           
  0x3f,                         
  { 0, 0, 0 }                   
};

// Analog pin used for emulated temperature reading
const int pin = A0;

// Use builtin led; active during conversion delay
GPIO<BOARD::D13> led;

void setup()
{
  led.output();
}

// This sketch uses approx. 1500 bytes (Uno) of program storage space,
// and less than 40 bytes for global variables (random access memory)
void loop()
{
  // Application could do something in the background before
  // handling incoming commands
  if (!owi.rom_command()) return;

  // DS18B20 emulation with analog read; mapping from 0..1023
  // to -128.00..127.75 C, 10-bits resolution. Set alarm according
  // to low and high thresholds
  int16_t value;
  switch (owi.read()) {
  case CONVERT_T:
    value = analogRead(pin) - 512;
    scratchpad.temperature = (value << 2);
    value >>= 2;
    owi.alarm(value >= scratchpad.high_trigger ||
              value <= scratchpad.low_trigger);
    led.high();
    break;
  case READ_SCRATCHPAD:
    owi.write(&scratchpad, sizeof(scratchpad));
    led.low();
    break;
  case WRITE_SCRATCHPAD:
    owi.read(&scratchpad.high_trigger, 3);
    break;
  case COPY_SCRATCHPAD:
  case RECALL_E:
  case READ_POWER_SUPPLY:
    break;
  }
}