SchedulerBenchmarkChannel.ino

Go to the documentation of this file.

#include <Scheduler.h>
#include <Scheduler/Channel.h>

// Check for SparkFun SAMD21 Breakout
#if defined(ARDUINO_ARCH_SAMD) && (USB_PID == 0x8D21)
#define Serial SerialUSB
#endif

// const size_t PAYLOAD_MAX = 1;
const size_t PAYLOAD_MAX = 8;
struct msg_t {
  uint8_t payload[PAYLOAD_MAX];
};

Channel chan;
unsigned long count = 0;

void setup()
{
  Serial.begin(57600);
  while (!Serial);
  Serial.println(F("SchedulerBenchmarkChannel: started"));
  Serial.flush();

  Scheduler.startLoop(producer);
  Scheduler.startLoop(consumer);
}

void loop()
{
  unsigned long start = millis();
  await(millis() - start >= 1000);
  Serial.print(count);
  Serial.print(F(" ("));
  Serial.print(1000000.0 / count);
  Serial.println(F(" us)"));
  Serial.flush();
  count = 0;
}

void producer()
{
  msg_t msg;
  while (1)
    chan.send(&msg, sizeof(msg));
}

void consumer()
{
  msg_t msg;
  while (1) {
    chan.recv(&msg, sizeof(msg));
    count += 1;
  }
}