SchedulerBlinkMax.ino

Go to the documentation of this file.

#include <Scheduler.h>

#if defined(ARDUINO_ARCH_AVR)
const size_t STACK_SIZE = 64;
#else
const size_t STACK_SIZE = 256;
#endif

int next_pin = 2;
int min_stack = STACK_SIZE;

void blink()
{
  // Allocate a pin and set output mode
  int pin = next_pin++;
  pinMode(pin, OUTPUT);

  // Toggle the pin on and off
  while (1) {
    int bytes = Scheduler.stack();
    if (bytes < min_stack) min_stack = bytes;
    digitalWrite(pin, HIGH);
    delay(500);
    digitalWrite(pin, LOW);
    delay(500);
  }
}

void setup()
{
  Serial.begin(57600);
  while (!Serial);
  Serial.println(F("SchedulerBlinkMax: started"));
  Serial.flush();

  // Start a blink task for each pin (use 64 byte stack)
  int tasks = 0;
  const int TASKS_MAX = NUM_DIGITAL_PINS - 2;
  while (tasks < TASKS_MAX && Scheduler.startLoop(blink, STACK_SIZE)) tasks++;
  Serial.print(millis());
  Serial.print(F(":setup::task="));
  Serial.println(tasks);

  Serial.print(millis());
  Serial.print(F(":setup::main:stack="));
  Serial.println(Scheduler.stack());
}

void loop()
{
  unsigned long start = millis();

  // Print the iteration count
  static unsigned int i = 0;
  Serial.print(millis());
  Serial.print(F(":loop::i="));
  Serial.println(i++);

  Serial.print(millis());
  Serial.print(F(":loop::main:stack="));
  Serial.println(Scheduler.stack());

  Serial.print(millis());
  Serial.print(F(":loop::min:stack="));
  Serial.println(min_stack);

  // Delay gracefully
  await((millis() - start) >= 1000);
}